HELP License/Users Problem

[Joe Boyle]

Chris Sharman sent this to the list a few years back, which might help.

I think the log file name cognos$license:cognosda.log differs between VAX or
alpha.

Below is the .COM I used to summarise the peaks (as well as modify the old
logs to contain running totals), if anyone's interested. More work could be
done on this, but this was adequate for me at the moment: next step would be
to separate different licences ($ SEARCH) and plot usage over time (pull the
running total calculated into Excel or something), or maybe study who's
actually using it.

-----------------
$ if p1.eqs."" then $ p1 := cognos$license:cognosda.log;-0
$ sum := cognos$license:cognosda.summary
$ file := 'f$search(p1)'
$ licences := \
$ on warning then goto $ fclose
$ control = f$env("control")
$ if f$locate("Y",control) then-
	$ set nocontrol=y   ! stop in here & the file's half done
$ ver = f$verify(0)
$ priv = f$setprv("sysprv")
$ licencebegin = f$file(file,"cdt")
$ open/read/write/error=quit log 'file'
$ rename 'file' .track;
$skip: read/end=fcloseok log line
$ if (f$locate(" (cognosd) ",line).ne.14) then $ goto skip
$ suf = f$ext(25,99,line)
$ opt = f$el(0," ",suf)
$ if (opt.nes."IN:") .and. (opt.nes."OUT:") then $ goto skip
$ licname = f$el(1," ",suf)
$ licx = f$locate("\"+licname+"\",licences)
$ if licx.eq.f$length(licences)
$ then	licences = licences + licname + "\"
$	licx = licx - 1
$	licencename'licx' = licname
$	licenceusers'licx' = 0
$	licencetotal'licx' = 0
$	licencemax'licx' = 0
$ endif
$ if opt.eqs."IN:"
$ then	licenceusers'licx' = licenceusers'licx' - 1
$ else	licenceusers'licx' = licenceusers'licx' + 1
$	licencetotal'licx' = licencetotal'licx' + 1
$	if (licenceusers'licx'.gt.licencemax'licx') then-
		$ licencemax'licx' = licenceusers'licx'
$ endif
$ usrs = f$fao("Now!4UL",licenceusers'licx')
$ line[16,7] := "''usrs'"
$ write/update log line
$ goto skip
$fcloseok:
$fclose: close log
$ x = f$verify(ver)
$ on warning then $ goto sumclose
$ licenceend = f$ext(0,14,"''line'")
$ if f$search(sum).eqs."" then $ copy nl: 'sum'
$ open/append sum 'sum'
$ write sum ""
$ write sum "Log File ",file
$ write sum "Started ",licencebegin,", last entry ",licenceend
$ write sum "Peak Accesses Name"
$ licx = 0
$licloop: if f$type(licencename'licx').eqs."" then $ goto sumclose
$ write sum f$fao("!4UL!9UL !AS",licencemax'licx',licencetotal'licx',-
		    licencename'licx')
$ licences[licx,1] :=
$ licx = f$locate("\",licences)
$ goto licloop
$sumclose: close sum
$ submit/notif/noprint 'f$env("procedure")'/par='p1'
$quit: x = f$setprv(priv)
$ if f$locate("Y",control) then $ set control=y
$ exit




-----Original Message-----
From: powerh-l-bounces+atla38=dsl.pipex.com at lists.sowder.com
[mailto:powerh-l-bounces+atla38=dsl.pipex.com at lists.sowder.com] On Behalf Of
Joe Boyle
Sent: 07 August 2007 15:43
To: 'T T'; powerh-l at lists.sowder.com
Subject: RE: HELP License/Users Problem

Could it be that you are running low on decent links ?


-----Original Message-----
From: Joe Boyle [mailto:atla38 at dsl.pipex.com] 
Sent: 07 August 2007 15:41
To: 'T T'; 'powerh-l at lists.sowder.com'
Subject: RE: HELP License/Users Problem

Have you tried below to see licenses in use ?

$ @cognos$license:COGNOS_LICENSE_SYMBOLS.COM
$ lmstat-a


-----Original Message-----
From: powerh-l-bounces+atla38=dsl.pipex.com at lists.sowder.com
[mailto:powerh-l-bounces+atla38=dsl.pipex.com at lists.sowder.com] On Behalf Of
T T
Sent: 07 August 2007 15:33
To: powerh-l at lists.sowder.com
Subject: HELP License/Users Problem

Hi,
      We are using an openVMS system with powerhouse 7.10G3, and for some 
strange reason
      though we have a license for 100 users in powerhouse, when the number 
of users reach about
      50 something and processes reach about 87, no one else can log on.Can 
you please assist
      me with this problem. Thanks in advance.


T.

_________________________________________________________________
More photos, more messages, more storage-get 2GB with Windows Live Hotmail. 
http://imagine-windowslive.com/hotmail/?locale=en-us&ocid=TXT_TAGHM_migratio
n_HM_mini_2G_0507

-- 
= = = = = = = = = = = = = = = = = = = = = = = = = = = =
Mailing list: powerh-l at lists.sowder.com
Subscribe: "subscribe" in message body to
powerh-l-request at lists.sowder.com
Unsubscribe: "unsubscribe <password>" in message body to
powerh-l-request at lists.sowder.com
http://lists.sowder.com/mailman/listinfo/powerh-l
This list is closed, thus to post to the list you must be a subscriber.
Add 'site:lists.sowder.com powerh-l' to your search terms to search the list
archive at Google.

-- 
= = = = = = = = = = = = = = = = = = = = = = = = = = = =
Mailing list: powerh-l at lists.sowder.com
Subscribe: "subscribe" in message body to
powerh-l-request at lists.sowder.com
Unsubscribe: "unsubscribe <password>" in message body to
powerh-l-request at lists.sowder.com
http://lists.sowder.com/mailman/listinfo/powerh-l
This list is closed, thus to post to the list you must be a subscriber.
Add 'site:lists.sowder.com powerh-l' to your search terms to search the list
archive at Google.