Axiant and OmniWindow

[Martin McDonough]

Barbara,

This is what I did for my users, they use '==' and '==*'

I replaced omniwindow with an axiant screen. Check what's been entered in
the master screens field input procedure and pass that value to the new
axiant screen.

The 'requested' fields I placed along the top of the screen, and listed a
cluster for the retrieved data.

I use systemvalues to hold what was originally entered by the user, in case
they wish to use '==*'

The temporary items (reset at startup) used in the request are initialized
to these systemvalues

I put a hot area over the cluster for the user to select their record

I changed the 'find' icon to do the designer procedure 'rest' (reset), so
that if the user had used '==*' initially and then wants to do a new
selection, the find procedure will execute.

This is the rest of my code,

Procedure Exit
Begin
  IF NOT SETSYSTEMVAL("ZZLU27_DESIGN_CG",T-DESIGN-CG)
    THEN ERROR "Could not set systemval ZZLU27_DESIGN_CG"
  IF NOT SETSYSTEMVAL("ZZLU27_PROD_DESC",T-PROD-DESC)
    THEN ERROR "Could not set systemval ZZLU27_PROD_DESC"
  IF NOT SETSYSTEMVAL("ZZLU27_SIZE",T-SIZE)
    THEN ERROR "Could not set systemval ZZLU27_SIZE"
  IF NOT SETSYSTEMVAL("ZZLU27_COLOUR",T-COLOUR)
    THEN ERROR "Could not set systemval ZZLU27_COLOUR"
  IF NOT SETSYSTEMVAL("ZZLU27_PRODUCT_GROUP",T-PRODUCT-GROUP)
    THEN ERROR "Could not set systemval ZZLU27_PRODUCT_GROUP"
  IF NOT SETSYSTEMVAL("ZZLU27_SUPPLIER",T-SUPPLIER)
    THEN ERROR "Could not set systemval ZZLU27_SUPPLIER"
  IF NOT SETSYSTEMVAL("ZZLU27_REPLENISH",T-REPLENISH)
    THEN ERROR "Could not set systemval ZZLU27_REPLENISH"
  IF NOT SETSYSTEMVAL("ZZLU27_PRODUCT",T-SELECTION)
    THEN ERROR "Could not set systemval ZZLU27_PRODUCT"
End

PROCEDURE PATH
BEGIN
  IF T-SELECTION <> "==*" OR &
     (T-SELECTION = "==*" AND &
      "" = GETSYSTEMVAL("ZZLU27_DESIGN_CG") AND &
      "" = GETSYSTEMVAL("ZZLU27_PROD_DESC") AND &
      "" = GETSYSTEMVAL("ZZLU27_PRODUCT_GROUP") AND &
      "" = GETSYSTEMVAL("ZZLU27_SIZE") AND &
      "" = GETSYSTEMVAL("ZZLU27_COLOUR") AND &
      "" = GETSYSTEMVAL("ZZLU27_SUPPLIER") AND &
      "" = GETSYSTEMVAL("ZZLU27_REPLENISH"))
    THEN BEGIN
      REQUEST T-DESIGN-CG
      REQUEST T-PROD-DESC
      REQUEST T-PRODUCT-GROUP
      REQUEST T-SIZE
      REQUEST T-COLOUR
      REQUEST T-SUPPLIER
      REQUEST T-REPLENISH
    END
END

PROCEDURE POSTPATH
BEGIN
  IF T-OMNIDEX-OK = "Y"
    THEN BEGIN
      Let T-ODX-CONTROL-CMD = &
         "RESET(PRODUCT-DETAILS)BASE " + T-ODX-BASEID + ";"
      Do External OMNIFINDCONTROL(T-ODX-CONTROL-CMD, &
                                  T-ODX-BUFFER, &
                                  T-ODX-MESSAGE)
      If T-ODX-MESSAGE <> ""
        Then Error = T-ODX-MESSAGE + "(Find)"
      IF T-DESIGN-CG <> ""
        THEN BEGIN
          Let T-ODX-CRITERIA = T-DESIGN-CG + ";"
          Let T-ODX-SEARCH-KEY = "PRODUCT-DETAILS.DESIGN-CG" + &
                "(HIDECOUNT BASE " + T-ODX-BASEID + ");"
          Do External OMNIFIND(T-ODX-SEARCH-KEY, &
                               T-ODX-CRITERIA, &
                               T-ODX-QUALIFY-COUNT, &
                               T-ODX-MESSAGE)
          If T-ODX-MESSAGE <> ""
            Then Error = T-ODX-MESSAGE + "(Find)"
        END
      IF T-PROD-DESC <> ""
        THEN BEGIN
          Let T-ODX-CRITERIA = T-PROD-DESC + ";"
          Let T-ODX-SEARCH-KEY = "PRODUCT-DETAILS.PROD-DESC" + &
                "(HIDECOUNT BASE " + T-ODX-BASEID + ");"
          Do External OMNIFIND(T-ODX-SEARCH-KEY, &
                               T-ODX-CRITERIA, &
                               T-ODX-QUALIFY-COUNT, &
                               T-ODX-MESSAGE)
          If T-ODX-MESSAGE <> ""
            Then Error = T-ODX-MESSAGE + "(Find)"
        END
;one of these for each temporary item
    END
END

PROCEDURE POSTFIND
BEGIN
  IF T-SELECTION = "==*" AND NOT &
     ("" = GETSYSTEMVAL("ZZLU27_PRODUCT") OR &
      "==" = GETSYSTEMVAL("ZZLU27_PRODUCT")[1:2])
    THEN BEGIN
      FOR DISPLAYED PRODUCT-DETAILS
        BEGIN
          IF PRODUCT OF PRODUCT-DETAILS = GETSYSTEMVAL("ZZLU27_PRODUCT")
            THEN LET T-COUNT = 1
        END
      IF T-COUNT = 0
        THEN PUSH NEXT DATA
      ELSE
        LET T-SELECTION = "==" ; SO WHEN NEXT DATA IS PRESSED IT WILL MOVE
ON
    END
END
    
PROCEDURE DESIGNER REST NODATA
BEGIN
  LET T-DESIGN-CG = ""
  LET T-PROD-DESC = ""
  LET T-SIZE = ""
  LET T-COLOUR = ""
  LET T-PRODUCT-GROUP = ""
  LET T-REPLENISH = ""
  LET T-SUPPLIER = ""
  LET T-SELECTION = ""
  PUSH FIND
END

Regards

Martin McDonough.

-----Original Message-----
From: Barbara Shelden [mailto:Barbara.Shelden@umpqua.edu] 
Sent: Monday, November 18, 2002 5:40 PM
To: powerh-l@lists.swau.edu
Subject: Axiant and OmniWindow


Are any of you using DISC's OmniWindow within Axiant?  We're running MPE/iX
7.0 using PH8.39D7.  Axiant is 3.0, Build 1175.  Have you found any other
way of doing 'hot key' lookups?

Thanks,

Barb Shelden
Sr Programmer/Analyst
Umpqua Community College

= = = = = = = = = = = = = = = = = = = = = = = = = = = =
Mailing list: powerh-l@lists.swau.edu
Subscribe: "subscribe" in message body to powerh-l-request@lists.swau.edu
Unsubscribe: "unsubscribe" in message body to
powerh-l-request@lists.swau.edu
http://lists.swau.edu/mailman/listinfo/powerh-l
This list is closed, thus to post to the list you must be a subscriber.


Disclaimer: 
This message contains information that may be privileged or confidential and
is intended only for the person to whom it is addressed. If you are not the
intended recipient, you are not authorized to read, print, retain, copy,
disseminate, distribute, or use this message or any part of this message. If
you receive this message in error, please notify the sender immediately by
using the reply option and delete all copies of this message.