AS400 - Popup confirmation

[Latimer, Richard]

Daniel 

This is probably more than you need as it's the whole process of submitting
a job (name t_info) to the batch subsystem either immediatlely or at some
time in the future ( t_date and t_time)

The bit that prompts for whether to  proceed or not is the block outlined
with asterisks . . . which looks like this when it's run:


                                                                  
 +--------------------------------------------------------------+ 
 :                           Warning                            : 
 :                                                              : 
 : Unprocessing and exception reports will be submitted at      : 
 : Date/Time as entered, continue ?                             : 
 :                                                              : 
 :  Enter=Confirm  F12=Cancel                                   : 
 +--------------------------------------------------------------+ 
              



cheers
Richard Latimer




PROCEDURE POSTUPDATE                                                   
 BEGIN                                                                 
  ;********************************************************************

  WARNING = trunc(t_info) + &                                          
           " will be submitted at Date/Time as entered, continue ?" &  
   CONFIRM                                                             
   IF CONFIRMOK                                                        
  ;********************************************************************* 
   THEN BEGIN                                                       
                                                                       
      IF t_date_ok = "Y"                                               
      THEN LET T_DATE2 = (CCON(t_date,8){7:2} + &                      
                                                                       
                          CCON(t_date,8){5:2} + &      
                          CCON(t_date,8){3:2})         
      ELSE LET t_date2 = "*current"                    
                                                       
      IF t_time_ok = "Y"                               
      THEN LET t_time2 = (CCON(t_time,4))              
      ELSE LET t_time2 = "*current"                    
                                                       
; generate the cmd to add a job to the scheduler.      
; the job will be run at the dte/tme as entered by the user     
                                                                
      LET t_command = &                                         
         "addjobscde job(" + t_job + ")"                 + &    
                    " cmd(sbmdbjob file(" + t_file + ")" + &    
                                 " mbr(" + t_mbr + "))"  + &    
                    " frq(*once)"                        + &    
                    " scddate(" + trunc(t_date2) + ")"   + &    
                    " scdtime(" + trunc(t_time2) + ")"   + &    
                                                                
                   " jobd(*usrprf)"                     + &    
                   " user(*current)"                           
                                                                
      RUN COMMAND t_command                                     
                                                                
      IF t_date_ok NE "Y" AND &                                 
         t_time_ok NE "Y"                                       
      THEN INFO = TRUNC(t_info) + " submitted NOW"

                                                                
      ELSE INFO = TRUNC(t_info) + " will be submitted on " + &  
             ccon(t_date,8){7:2}+ "/" + &                       
             ccon(t_date,8){5:2}+ "/" + &                       
             ccon(t_date,8){3:2}+ " " + &                       
                  "at "              + &                        
             ccon(t_time,4){1:2}+ ":" + &                       
             ccon(t_time,4){3:2}                                
 

      LET t_time_ok = ""                                    
      LET t_date_ok = ""                                    
      LET t_run = "Y"                                       
                                                            
      END ; confirmok                                       
                                                            
   ELSE ERROR = TRUNC(t_info) + " not submitted."           
                                                            
   RETURN  
END 



                                                 
                                                            
-----Original Message-----
From: Daniel Mielke [mailto:DMielke@aicfunds.com]
Sent: Wednesday, 28 March 2001 10:24 a.m.
To: 'powerh-l@cube.swau.edu'
Subject: AS400 - Popup confirmation 


Hello all,

I want to build a popup screen in QUICK to confirm with the user before
proceeding with an update job.  I only want the option of F12 to Cancel, and
ENTER to confirm.

Something like this:
+-----------------------------------+
:                                    :
:    Proceed with job X?    :
:                                     :
:Enter=Conf F12=Cancel  :                              :
+-----------------------------------+

How would I go about such a thing on an AS400 platform?


> BUY. HOLD. AND PROSPER.
> 
> Daniel Mielke
> Senior User Analyst
> AIC Limited
> 1-888-710-4242 (4614)
> dmielke@aicfunds.com
> www.aicfunds.com
> 

= = = = = = = = = = = = = = = = = = = = = = = = = = = =
Mailing list: powerh-l@lists.swau.edu
Subscribe: "subscribe" in message body to powerh-l-request@lists.swau.edu
Unsubscribe: "unsubscribe" in message body to
powerh-l-request@lists.swau.edu
http://lists.swau.edu/mailman/listinfo/powerh-l
This list is closed, thus to post to the list you must be a subscriber.