PowerHouse inside an MPE/X "WHILE" loop
Cummings, Ken P.
KPCUMMIN@gapac.com
Wed, 7 Oct 1998 10:14:02 -0400
This message is in MIME format. Since your mail reader does not understand
this format, some or all of this message may not be legible.
------ =_NextPart_000_01BDF1FC.C44945E0
Content-Type: text/plain
For those of you that requested the code, here it is. BTW, the ACKPRINT
file is a mailbox (VAM) file.
<<Opjc099a.job>> <<Opsz099a.qui>> <<Opsp099b.qtp>> <<Opsz099c.qui>>
The documentation I found is some inline documentation in one of the jobs in
the client application. Apparently someone has come across this problem
before. Here it is:
!comment Before we do any processing, let's build a command stream for
!comment Qedit to execute. This is necessary because, in a job stream,
!comment data is only available the first time thru a while...endwhile
!comment loop (honest!). If you embed the Qedit commands in the job
!comment under the RUN QEDIT..., the job will abort the second time it
!comment runs Qedit. We'll use the parm= and stdin= on the RUN statement
!comment to tell Qedit to use the following file...
> ----------
> From: Leonard Berkowitz[SMTP:Leonard_Berkowitz@tufts-health.com]
> Sent: Wednesday, October 07, 1998 9:49 AM
> To: Cummings, Ken P.
> Subject: Re: PowerHouse inside an MPE/X "WHILE" loop
>
>
>
> <<documentation on this problem that indicates that this is the case.>>
>
> What is the case? the while loop? How can that be? Wouldn't QUIZ close
> after each
> execution within the loop?
> ========================
> Leonard S. Berkowitz
> mailto:Leonard_Berkowitz@tufts-health.com
> phone: (617) 972-9400 ext. 3250
> fax: (617) 923-5555
>
>
>
>
>
>
>
>
> "Cummings, Ken P." <KPCUMMIN@gapac.com> on 10/07/98 09:45:40 AM
>
> To: "'PowerHouse Discussion List'" <powerh-l@lists.swau.edu>
> cc: (bcc: Leonard Berkowitz/THP)
> Subject: PowerHouse inside an MPE/X "WHILE" loop
>
>
>
>
> I am running a QUIZ and QTP routines within a MPE/X "WHILE" loop.
> Unfortunately, I have found that QUIZ returns no records in the second and
> subsequent passes. The file I am accessing definitely has records in it,
> but after the first pass through the while loop (in which records are
> successfully returned), apparently the data in the file is not accessible
> to
> PowerHouse. I have even found some documentation on this problem that
> indicates that this is the case.
>
> Does anyone know of a way around this problem? Is there a way of
> resetting
> PowerHouse or the input file so that QUIZ will recognize that there are
> records and process the file?
>
> Thanks in advance.
>
> ----------------------------------------------------------------------
> Ken Cummings
> Senior Consultant
> VersaComp Systems Inc.
> cummingsk@versacomp.com
> kpcummin@gapac.com
> 404-652-6250
>
> = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
> =
> Subscribe: "subscribe powerh-l" in message body to
> majordomo@lists.swau.edu
> Unsubscribe: "unsubscribe powerh-l" in message to majordomo@lists.swau.edu
> powerh-l@lists.swau.edu is gatewayed one-way to bit.listserv.powerh-l
> This list is closed, thus to post to the list, you must be a subscriber.
>
>
>
>
>
>
------ =_NextPart_000_01BDF1FC.C44945E0
Content-Type: application/octet-stream;
name="Opjc099a.job"
Content-Disposition: attachment;
filename="Opjc099a.job"
!JOB OPJC099A,MANAGER.FNGTEST;PRI=ES
!COMMENT; ********************************************
!COMMENT; *** COMMON ORDER PROCESSING SYSTEM ***
!COMMENT; *** ***
!COMMENT; *** Runs during the day to print Order ***
!COMMENT; *** Acknowledgements in the background. ***
!COMMENT; *** ***
!COMMENT; *** 10/06/98 KPC - Original Program. ***
!COMMENT; ********************************************
!SCH
!COMMENT *********************************************************
!COMMENT ** Define ACKPRINT file as shared.
!COMMENT
!FILE ACKPRINT=ACKPRINT.DATA,OLD;SHR;GMULTI;LOCK
!COMMENT
!COMMENT *********************************************************
!COMMENT ** Build a flag file. If this is missing the
!COMMENT ** job will stop running.
!COMMENT
!PURGE ACKFLAG.DATA
!CONTINUE
!BUILD ACKFLAG.DATA;REC=-80,,F,ASCII;DISC=1
!COMMENT
!COMMENT *********************************************************
!COMMENT ** Print Order Acknowledgements
!COMMENT
!WHILE FINFO('ACKFLAG.DATA',0) DO
! QUIZ
USE OPSZ099A.QUIZ NOL
EXIT
! QTP
USE OPSP099B.QTP NOL
EXIT
! QUIZ
USE OPSZ099C.QUIZ NOL
EXIT
! CONTINUE
! IF FINFO('ACKPRINT','EOF') = 0 THEN
! ECHO No records in ACKPRINT file - pausing for 5 minutes
! PAUSE 30
! ENDIF
!ENDWHILE
!COMMENT
!ECHO OPJC099A was stopped normally.
!CONTINUE
!RUN SIGNALER.MAESTRO.CCC
!EOJ
------ =_NextPart_000_01BDF1FC.C44945E0
Content-Type: application/octet-stream;
name="Opsz099a.qui"
Content-Disposition: attachment;
filename="Opsz099a.qui"
;***********************************************************************
;*
;* PROGRAM NAME: OPSZ099A.QUIZ - Freight Reject Report Extract Step 1
;*
;* WRITTEN BY: Ken Cummings
;*
;* DATE WRITTEN: Sept 18, 1998
;*
;* DESCRIPTION: Reads the ACKPRINT file.
;*
;* JOB STREAM OPJZ099.JOB - Runs online during the day
;*
;* MODIFICATION HISTORY
;* --------------------
;* MOD000 09/18/98 Ken Cummings Original Program.
;***********************************************************************
SET REPORT LIMIT 1
ACCESS ACKPRINT
SORT ON ORDER-NUM
SET SUBFILE NAME OPFZ099A KEEP AT ORDER-NUM
REPORT SUMMARY ALL
GO ;********************************************************************
------ =_NextPart_000_01BDF1FC.C44945E0
Content-Type: application/octet-stream;
name="Opsp099b.qtp"
Content-Transfer-Encoding: quoted-printable
Content-Disposition: attachment;
filename="Opsp099b.qtp"
;***********************************************************************=
;*
;* PROGRAM NAME: OPSZ099A.QTP - Freight Reject Report Extract
;*
;* WRITTEN BY: Ken Cummings
;*
;* DATE WRITTEN: Sept 18, 1998
;*
;* DESCRIPTION: Creates from the ACKPRINT file the OPFP099C data =
file
;* which is used to print the Order Acknowledgement in
;* OPSZ099A. The ACKPRINT file is a VAM ("mailbox") =
file
;* so whenever a record is read, it will automatically
;* be deleted from the file.
;*
;* JOB STREAM OPJZ099.JOB - Runs online during the day
;*
;* MODIFICATION HISTORY
;* --------------------
;* MOD000 09/18/98 Ken Cummings Original Program.
;***********************************************************************=
SET PROCESS LIMIT 1000
SET LOCK FILE UPDATE
RUN OPSP099A
;-----------------------------------------------------------------------=
REQUEST CREATE-MPE-QUIZDEFS
ACCESS *OPFZ099A &
LINK (USER-ORIGIN-CD + ASCII(DEVICE-NUMBER,2) + "ACKNOWLE") &
TO LOC-SITE-PROG OF MSREPDEV
DEFINE D-COMMAND CHAR*60 =3D &
":FILE OPSZ099C;DEV=3D" + TRUNC(USER-DEV-CLASS OF MSREPDEV) + =
",8,1"
DEFINE D-COMMAND2 CHAR*60 =3D &
":ECHO OPJC099A printed Order " + ORDER-NUM + " at " + &
ASCII(SYSTIME/1000000) + ":" + &
ASCII(MOD(SYSTIME/10000,100)) + "." + &
ASCII(MOD(SYSTIME/100,100))
SUBFILE OPSZ099C.QUIZDEF TEMP NODICT ALIAS FILEEQ &
INCLUDE D-COMMAND
SUBFILE OPSZ099D.QUIZDEF TEMP NODICT ALIAS ECHO &
INCLUDE D-COMMAND2
;-----------------------------------------------------------------------=
REQUEST CREATE-FILE-OF-ORDERS
ACCESS *OPFZ099A &
LINK ORDER-NUM TO ORDER-NUM OF ORDER OPT &
LINK SHIP-FROM-CODE OF ORDER TO SHIP-FROM-CODE OF LOCATIONS OPT &
LINK (ORDER-NUM OF ORDER[1:2]) &
TO SHIP-FROM-CODE OF LOCATIONS ALIAS SALES-OFFICE OPT &
LINK SOLD-TO-CODE OF ORDER TO SOLD-TO-CODE OF CUST-SOLD-TO OPT =
&
LINK (ASCII(SOLD-TO-CODE OF ORDER,6) + &
ASCII(SHIP-TO-CODE OF ORDER,4)) &
TO SOLD-SHIP-TO OF CUST-SHIP-TO &
LINK CARRIER OF ORDER TO CARRIER OF CARRIERS OPT &
LINK ("FRT" + FREIGHT-CODE OF ORDER) &
TO TABLE-KEY OF OPTABLES ALIAS FREIGHT-CODES OPT &
LINK ("OS" + ASCII(STATUS-CODE OF ORDER,4)) &
TO TABLE-KEY OF OPTABLES ALIAS STATUS-CODES OPT
DEFINE D-SOLD-TO-NAME-1 CHAR*36 =3D CUST-NAME-1 OF CUST-SOLD-TO
DEFINE D-SOLD-TO-NAME-2 CHAR*36 =3D CUST-NAME-2 OF CUST-SOLD-TO
DEFINE D-SOLD-TO-ADDR-1 CHAR*30 =3D CUST-ADDR-1 OF CUST-SOLD-TO
DEFINE D-SOLD-TO-COUNTRY CHAR*12 =3D COUNTRY OF CUST-SOLD-TO
DEFINE D-SOLD-TO-CSZ CHAR*36 =3D &
TRUNC(CITY OF CUST-SOLD-TO) + ", " + &
PROVINCE-CODE OF CUST-SOLD-TO + " " + &
ZIP-POST-CODE OF CUST-SOLD-TO
DEFINE D-SHIP-TO-NAME-1 CHAR*36 =3D CUST-NAME-1 OF CUST-SHIP-TO
DEFINE D-SHIP-TO-NAME-2 CHAR*36 =3D CUST-NAME-2 OF CUST-SHIP-TO
DEFINE D-SHIP-TO-BRANCH CHAR*36 =3D CUST-BRANCH OF CUST-SHIP-TO
DEFINE D-SHIP-TO-ADDR-1 CHAR*30 =3D CUST-ADDR-1 OF CUST-SHIP-TO
DEFINE D-SHIP-TO-COUNTRY CHAR*12 =3D COUNTRY OF CUST-SHIP-TO
DEFINE D-SHIP-TO-CSZ CHAR*36 =3D &
TRUNC(CITY OF CUST-SHIP-TO) + ", " + &
PROVINCE-CODE OF CUST-SHIP-TO + " " + &
ZIP-POST-CODE OF CUST-SHIP-TO
DEFINE D-STATUS-DESC CHAR*20 =3D TABLE-DATA OF STATUS-CODES[1:20]
DEFINE D-SHIP-FROM-NAME CHAR*30 =3D SHIP-FROM-NAME OF LOCATIONS
DEFINE D-SALES-OFFICE-NAME CHAR*30 =3D SHIP-FROM-NAME OF SALES-OFFICE
SORT ON ORDER-NUM OF ORDER
SUBFILE OPFP099B KEEP AT ORDER-NUM INCLUDE &
ORDER-NUM OF ORDER, &
STATUS-CODE OF ORDER, &
D-STATUS-DESC, &
SHIP-FROM-CODE OF ORDER, &
D-SHIP-FROM-NAME, &
D-SALES-OFFICE-NAME, &
SOLD-TO-CODE OF ORDER, &
D-SOLD-TO-NAME-1, &
D-SOLD-TO-NAME-2, &
D-SOLD-TO-ADDR-1, &
D-SOLD-TO-CSZ, &
D-SOLD-TO-COUNTRY, &
SHIP-TO-CODE OF ORDER, &
D-SHIP-TO-NAME-1, &
D-SHIP-TO-NAME-2, &
D-SHIP-TO-ADDR-1, &
D-SHIP-TO-BRANCH, &
D-SHIP-TO-CSZ, &
D-SHIP-TO-COUNTRY, &
FREIGHT-CODE OF ORDER, &
FRT-TERMS-DESC OF FREIGHT-CODES, &
CARRIER OF ORDER, &
CARRIER-NAME OF CARRIERS, &
SCAC-CODE OF CARRIERS, &
MATERIAL-WEIGHT OF ORDER, &
LOADING-DATE OF ORDER, &
LOADING-TIME OF ORDER, &
REQ-SHIP-DATE OF ORDER, &
REQ-SHIP-TIME OF ORDER, &
ST-PROV-LIC-NUM OF CUST-SHIP-TO, &
SHIP-WITH-LINK OF ORDER, &
ORIGINATOR OF ORDER, &
DATE-ENTERED OF ORDER, &
INVOICE-DATE OF ORDER, &
JOB-NAME OF ORDER
;-----------------------------------------------------------------------=
REQUEST ADD-INSTRUCTIONS-LINES
ACCESS *OPFP099B &
LINK ORDER-NUM TO ORDER-NUM OF INSTR
SORT ON ORDER-NUM, INSTR-TYPE, INSTR-SEQ
DEFINE D-PRODUCT-CODE CHAR*6 =3D ""
DEFINE D-LINE-COUNT NUM*2 =3D 0
DEFINE D-PRINT-LINE CHAR*80 =3D &
INSTR-TYPE OF INSTR + &
" " + &
INSTR OF INSTR
DEFINE D-PRINT-SORT NUM*2 =3D 1
SUBFILE OPFP099C KEEP INCLUDE &
OPFP099B, &
D-PRODUCT-CODE, &
D-LINE-COUNT, &
D-PRINT-SORT, &
D-PRINT-LINE
;-----------------------------------------------------------------------=
REQUEST ADD-HEADING-LINE
ACCESS *OPFP099B
SORT ON ORDER-NUM
DEFINE D-PRODUCT-CODE CHAR*6 =3D ""
DEFINE D-LINE-COUNT NUM*2 =3D 0
DEFINE D-PRINT-LINE CHAR*80 =3D &
"Product Quantity Description Volume (MSF)" &
+ " Unit Price"
DEFINE D-PRINT-SORT NUM*2 =3D 2
SUBFILE OPFP099C KEEP APPEND INCLUDE &
OPFP099B, &
D-PRODUCT-CODE, &
D-LINE-COUNT, &
D-PRINT-SORT, &
D-PRINT-LINE
;-----------------------------------------------------------------------=
REQUEST ADD-ORDER-ITEMS-LINES
ACCESS *OPFP099B &
LINK ORDER-NUM TO ORDER-NUM OF ORDER-ITEMS OPT &
LINK PRODUCT-CODE TO PRODUCT-CODE OF PRODUCT OPT &
LINK GLID-CODE TO GLID-CODE OF GLID OPT
SORT ON ORDER-NUM OF OPFP099B, PRODUCT-CODE OF ORDER-ITEMS, &
LINE-COUNT OF ORDER-ITEMS
TEMP T-LINE-CTR NUM*2
DEFINE D-PRODUCT-CODE CHAR*6 =3D &
PRODUCT-CODE OF ORDER-ITEMS
DEFINE D-LINE-COUNT NUM*2 =3D &
LINE-COUNT OF ORDER-ITEMS
DEFINE D-DESCR-1 CHAR*28 =3D &
DESCR-1-FULL OF PRODUCT IF RECORD PRODUCT EXISTS ELSE &
GLID-DESCR OF GLID IF RECORD GLID EXISTS ELSE &
"*** PRODUCT NOT FOUND IN COPS ****"
DEFINE D-DESCR-2 CHAR*28 =3D &
DESCR-2-FULL OF PRODUCT IF RECORD PRODUCT EXISTS ELSE " "
DEFINE D-STD-ORD-QUANTITY CHAR*11 =3D &
ASCII(STD-ORD-QUANTITY OF ORDER-ITEMS/1000) + &
"." + ASCII(MOD(STD-ORD-QUANTITY OF ORDER-ITEMS,1000),3)
DEFINE D-STD-ORD-QUANTITY2 CHAR*11 =3D RJ(D-STD-ORD-QUANTITY)
DEFINE D-QTY-ORDERED CHAR*11 =3D &
ASCII(QTY-ORDERED OF ORDER-ITEMS/1000) + &
"." + ASCII(MOD(QTY-ORDERED OF ORDER-ITEMS,1000),3)
DEFINE D-QTY-ORDERED2 CHAR*11 =3D RJ(D-QTY-ORDERED)
DEFINE D-LIST-PRICE CHAR*9 =3D &
ASCII(LIST-PRICE OF ORDER-ITEMS/100) + &
"." + ASCII(MOD(LIST-PRICE OF ORDER-ITEMS,100),2)
DEFINE D-LIST-PRICE2 CHAR*9 =3D RJ(D-LIST-PRICE)
DEFINE D-PRINT-LINE CHAR*80 =3D &
PRODUCT-CODE OF ORDER-ITEMS + &
" " + D-STD-ORD-QUANTITY2 + &
" " + STD-ORDER-UNIT OF PRODUCT + &
" " + D-DESCR-1 + &
" " + D-QTY-ORDERED2 + &
" " + D-LIST-PRICE2 + &
"/" + STD-PRICE-UNIT OF PRODUCT &
IF T-LINE-CTR =3D 1 ELSE &
" " + D-DESCR-2 &
IF T-LINE-CTR =3D 2 ELSE &
" " + NOTE-1 OF ORDER-ITEMS &
IF T-LINE-CTR =3D 3 ELSE &
" " + NOTE-2 OF ORDER-ITEMS &
IF T-LINE-CTR =3D 4 ELSE &
" " + NOTE-3 OF ORDER-ITEMS &
IF T-LINE-CTR =3D 5 ELSE &
" " + NOTE-4 OF ORDER-ITEMS &
IF T-LINE-CTR =3D 6 ELSE &
" " + NOTE-5 OF ORDER-ITEMS &
IF T-LINE-CTR =3D 7 ELSE " "
DEFINE D-PRINT-SORT NUM*2 =3D 3
ITEM T-LINE-CTR =3D 1
SUBFILE OPFP099C KEEP APPEND INCLUDE &
OPFP099B, &
D-PRODUCT-CODE, &
D-LINE-COUNT, &
D-PRINT-SORT, &
D-PRINT-LINE
ITEM T-LINE-CTR =3D 2
SUBFILE OPFP099C KEEP APPEND ALIAS OPFP099C-LINE-2 &
IF D-DESCR-2 <> " " INCLUDE &
OPFP099B, &
D-PRODUCT-CODE, &
D-LINE-COUNT, &
D-PRINT-SORT, &
D-PRINT-LINE
ITEM T-LINE-CTR =3D 3
SUBFILE OPFP099C KEEP APPEND ALIAS OPFP099C-LINE-3 &
IF NOTE-1 OF ORDER-ITEMS <> " " INCLUDE &
OPFP099B, &
D-PRODUCT-CODE, &
D-LINE-COUNT, &
D-PRINT-SORT, &
D-PRINT-LINE
ITEM T-LINE-CTR =3D 4
SUBFILE OPFP099C KEEP APPEND ALIAS OPFP099C-LINE-4 &
IF NOTE-2 OF ORDER-ITEMS <> " " INCLUDE &
OPFP099B, &
D-PRODUCT-CODE, &
D-LINE-COUNT, &
D-PRINT-SORT, &
D-PRINT-LINE
ITEM T-LINE-CTR =3D 5
SUBFILE OPFP099C KEEP APPEND ALIAS OPFP099C-LINE-5 &
IF NOTE-3 OF ORDER-ITEMS <> " " INCLUDE &
OPFP099B, &
D-PRODUCT-CODE, &
D-LINE-COUNT, &
D-PRINT-SORT, &
D-PRINT-LINE
ITEM T-LINE-CTR =3D 6
SUBFILE OPFP099C KEEP APPEND ALIAS OPFP099C-LINE-6 &
IF NOTE-4 OF ORDER-ITEMS <> " " INCLUDE &
OPFP099B, &
D-PRODUCT-CODE, &
D-LINE-COUNT, &
D-PRINT-SORT, &
D-PRINT-LINE
ITEM T-LINE-CTR =3D 7
SUBFILE OPFP099C KEEP APPEND ALIAS OPFP099C-LINE-7 &
IF NOTE-5 OF ORDER-ITEMS <> " " INCLUDE &
OPFP099B, &
D-PRODUCT-CODE, &
D-LINE-COUNT, &
D-PRINT-SORT, &
D-PRINT-LINE
GO =
;********************************************************************
------ =_NextPart_000_01BDF1FC.C44945E0
Content-Type: application/octet-stream;
name="Opsz099c.qui"
Content-Disposition: attachment;
filename="Opsz099c.qui"
;***********************************************************************
;*
;* PROGRAM NAME: OPSZ099C.QUIZ - Freight Reject Report
;*
;* WRITTEN BY: Ken Cummings
;*
;* DATE WRITTEN: Sept 18, 1998
;*
;* DESCRIPTION: Prints the Order Acknowledgement from the OPFP099C
;* file.
;*
;* JOB STREAM OPJZ099.JOB - Runs online during the day
;*
;* MODIFICATION HISTORY
;* --------------------
;* MOD000 09/18/98 Ken Cummings Original Program.
;***********************************************************************
ACCESS *OPFP099C
USE OPSZ099C.QUIZDEF ; Use Device Name QUIZDEF generated in OPSP099B
USE OPSZ099D.QUIZDEF NOL ; Use QUIZDEF generated in OPSP099B to echo ord
DEFINE D-SALES-OFFICE CHAR*2 = &
ORDER-NUM[1:2]
SORT ON ORDER-NUM, D-PRINT-SORT, D-LINE-COUNT
DEFINE D-CARRIER-NAME CHAR*34 = &
"TO BE ASSIGNED" IF CARRIER = 999999 ELSE &
"TO BE ASSIGNED BY TDS" IF CARRIER = 0 ELSE &
CARRIER-NAME
PAGE HEADING &
TAB 001 "RUN DATE:"&
TAB 011 SYSDATE &
TAB 022 SYSTIME &
TAB 032 "GEORGIA-PACIFIC GYPSUM" &
TAB 072 "PAGE:" SYSPAGE PIC "^^^" &
SKIP &
TAB 001 "REPORT: " "OPSZ099C" &
TAB 032 "ORDER ACKNOWLEDGEMENT" &
SKIP 3 &
TAB 001 "Order Number:" &
TAB 015 ORDER-NUM &
SKIP &
TAB 001 "Order Status:" &
TAB 015 STATUS-CODE PIC "^^" &
TAB 017 "-" &
TAB 018 D-STATUS-DESC &
TAB 041 "Order Entered:" &
TAB 056 DATE-ENTERED &
TAB 068 "By" &
TAB 071 ORIGINATOR &
SKIP 2 &
TAB 001 "Sales Office:" &
TAB 015 D-SALES-OFFICE &
TAB 017 "-" &
TAB 018 D-SALES-OFFICE-NAME &
TAB 041 "Loading Date:" &
TAB 056 LOADING-DATE &
TAB 068 LOADING-TIME PIC "^^:^^" &
SKIP &
TAB 001 "Shipped From:" &
TAB 015 SHIP-FROM-CODE &
TAB 017 "-" &
TAB 018 D-SHIP-FROM-NAME &
TAB 041 "Req Ship Date:" &
TAB 056 REQ-SHIP-DATE &
TAB 068 REQ-SHIP-TIME PIC "^^:^^" &
SKIP 2 &
TAB 041 "Job Name:" &
TAB 011 JOB-NAME &
SKIP 2 &
TAB 001 "Sold-To:" &
TAB 010 SOLD-TO-CODE &
TAB 041 "Ship-To:" &
TAB 050 SHIP-TO-CODE &
TAB 056 "Lic Num:" &
TAB 067 ST-PROV-LIC-NUM &
SKIP &
TAB 001 D-SOLD-TO-NAME-1 &
TAB 041 D-SHIP-TO-NAME-1 &
SKIP &
TAB 001 D-SOLD-TO-NAME-2 &
TAB 041 D-SHIP-TO-NAME-2 &
SKIP &
TAB 001 D-SOLD-TO-ADDR-1 &
TAB 041 D-SHIP-TO-ADDR-1 &
SKIP &
TAB 001 D-SOLD-TO-CSZ &
TAB 041 D-SHIP-TO-CSZ &
SKIP &
TAB 001 D-SOLD-TO-COUNTRY &
TAB 041 D-SHIP-TO-COUNTRY &
SKIP 2 &
TAB 001 "Freight Code:" &
TAB 015 FREIGHT-CODE &
TAB 017 "-" &
TAB 018 FRT-TERMS-DESC &
TAB 041 "Material Weight:" &
TAB 058 MATERIAL-WEIGHT &
SKIP &
TAB 001 "Carrier:" &
TAB 010 CARRIER &
TAB 016 "-" &
TAB 017 D-CARRIER-NAME &
TAB 049 "(" &
TAB 050 SCAC-CODE &
TAB 054 ")" &
SKIP 2
HEADING AT ORDER-NUM SKIP PAGE
HEADING AT D-LINE-COUNT SKIP 2
REPORT &
D-PRINT-LINE
USE PRTSETUP.QUIZDEF NOLIST
SET REPORT DEVICE PRINTER NAME OPSZ099C
SET PAGE WIDTH 132
GO ;********************************************************************
------ =_NextPart_000_01BDF1FC.C44945E0--
= = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
Subscribe: "subscribe powerh-l" in message body to majordomo@lists.swau.edu
Unsubscribe: "unsubscribe powerh-l" in message to majordomo@lists.swau.edu
powerh-l@lists.swau.edu is gatewayed one-way to bit.listserv.powerh-l
This list is closed, thus to post to the list, you must be a subscriber.